Npc对话框动态进度条功能以及自定义进度条和自定义属性示例脚本

红名村

Npc对话框动态进度条功能以及自定义进度条和自定义属性示例脚本,自定义装备进度条 值+20带100%触发 检测装备进度条,进度部分解释 如必备补丁的620 621图片，一个是背景，一个是进度部分，2个图片大小不一样，背景大些，进度部分小些，进度部分要偏移

1.Npc对话框动态进度条功能

1. <测试2/@测试2>
   
2. 　\<ProgressBar:0:0:1:620:630:6:100:4:1:100:200:190:0:249:0:0:%p／%m:NewopUI.pak中/@Label>
   
3. 　\<ProgressBar:0:0:24:770:771:1:100:0:0:100:200:170:3:255:0:0:%r%:ui_n.pak中/@Label>

复制代码

1. [@aaa]
   
2. ;<ProgressBar:X:Y:F:B:P:C:T:X2:Y2:N:X:V:D:L:X3:Y3:显示文字:备注信息>

复制代码

X, Y: 微调坐标
F: WIL文件序号(详见引擎：查看-列表信息(二)-WIL资源)
B: 进度条背景为文件中的第几个图片
P: 进度条进度部分为文件中的第几个图片
C: 进度条进度部分播放张数
T: 进度条进度部分播放间隔
X2: 进度条进度部分X坐标偏移
Y2: 进度条进度部分Y坐标偏移
N: 进度条最小值
X: 进度条最大值
V: 进度条当前值
D: 进度条方向(0:左向右, 1:右向左, 2:上向下, 3:下向上)
L: 进度条文字颜色(0-255)
X3: 进度条文字偏移X
Y3: 进度条文字偏移Y
显示文字：%p当前值, %m最大值, %r百分比

进度部分解释
如必备补丁的620 621图片，一个是背景，一个是进度部分，2个图片大小不一样，背景大些，进度部分小些，进度部分要偏移

2.自定义进度条和自定义属性示例脚本

[@main]
#SAY
\\
自定义装备进度条 <开启/@开启装备进度条> <值+20【带100%触发】/@装备进度条值+> <检测/@检测装备进度条> <取值/@取装备进度条值>\\

自定义装备属性 <开启/@开启装备属性> <值+20/@装备属性值+> <检测/@检测装备属性值> <取值/@取装备属性值>\\


;==============================================================
[@开启装备进度条]
#ACT
; 开启自定义装备进度条0
SETCUSTOMITEMPROGRESSBAR 1 0 0 1
; 设置自定义装备进度条0的名称
SETCUSTOMITEMPROGRESSBAR 1 0 1 刀魂%p-%m：
; 设置自定义装备进度条0的名称
SETCUSTOMITEMPROGRESSBAR 1 0 1 刀魂%r%：
; 设置自定义装备进度条0的颜色
SETCUSTOMITEMPROGRESSBAR 1 0 2 255
; 设置自定义装备进度条0的图片播放张数
SETCUSTOMITEMPROGRESSBAR 1 0 3 15
; 设置自定义装备进度条0上的值按数值方式显示
SETCUSTOMITEMPROGRESSBAR 1 0 4 2
; 设置自定义装备进度条0的最大值为 1000
SETCUSTOMITEMPROGRESSBARVALUE 1 0 0 = 1000
; 设置自定义装备进度条0的当前值为 60%
SETCUSTOMITEMPROGRESSBARVALUE 1 0 2 = 60


;==============================================================
[@取装备进度条值]
#ACT
GetCustomItemProgressbarValue 1 0 0 <$STR(N1)>
GetCustomItemProgressbarValue 1 0 1 <$STR(N2)>
GetCustomItemProgressbarValue 1 0 2 <$STR(N3)>
SENDMSG 6 最大值<$STR(N1)>
SENDMSG 6 当前值<$STR(N2)>
SENDMSG 6 百分比值<$STR(N2)>%


;==============================================================
[@武器进度条0满100%]
#ACT
SENDMSG 6 ★★★★★★★★进度条满了★★★★★★★★★★。。。。。

[@装备进度条值+]
#IF
CheckCustomItemProgressbarValue 1 0 2 < 100
#ACT
; 设置自定义装备进度条0的当前值+20
SETCUSTOMITEMPROGRESSBARVALUE 1 0 1 + 20
#ELSEACT
BREAK

;判断进度条是否达到100%
#IF
CheckCustomItemProgressbarValue 1 0 2 = 100
#ACT
goto @武器进度条0满100%

;==============================================================
[@检测装备进度条]
#IF
CheckCustomItemProgressbarValue 1 0 2 > 40
#ACT
SENDMSG 6 检测成功

;==============================================================
[@开启装备属性]
#IF
#ACT
SetCustomItemText 1 我的自定义属性显示
SetCustomItemTextColor 1 249
;设置自定义装备属性0的颜色
SetCustomItemAbil 1 0 0 250
;设置自定义装备属性0绑定属性1
SetCustomItemAbil 1 0 1 1
;设置自定义装备属性0的显示位置为1
SetCustomItemAbil 1 0 2 1
;设置自定义装备属性0为百分比显示
SetCustomItemAbil 1 0 3 1
;设置自定义装备属性0的值
SetCustomItemValue 1 0 = 20

;-------------------------------

;设置自定义装备属性1的颜色
SetCustomItemAbil 1 1 0 249
;设置自定义装备属性1绑定属性2
SetCustomItemAbil 1 1 1 2
;设置自定义装备属性1的显示位置为2
SetCustomItemAbil 1 1 2 2
;设置自定义装备属性1为非百分比
SetCustomItemAbil 1 1 3 0
;设置自定义装备属性1的值
SetCustomItemValue 1 1 = 40

;================================================================
[@装备属性值+]
#ACT
SetCustomItemValue 1 0 + 20

;================================================================
[@检测装备属性值]
#IF
CheckCustomItemValue 1 0 > 100
#ACT
SENDMSG 6 装备属性值0大于100

;================================================================
[@取装备属性值]
#ACT
GetCustomItemValue 1 0 <$STR(N1)> <$STR(N2)>

; 第2个变量不为0时，表示百分比
#IF
Equal <$STR(N2)> 0
#ACT
SENDMSG 6 装备属性值0为<$STR(N1)>
#ELSEACT
SENDMSG 6 装备属性值0为<$STR(N1)>%





=====================================================================================================================


相关说明：
改物品的属性，需用LOCKUPDATEITEM锁定要修改的装备
---------
物品在人物身上。
LOCKUPDATEITEM XX
UPDATEITEM

--------------

物品不在人物身上
LOCKUPDATEITEM XX
UPDATEITEM